JSON Editors

4gl调用WEB API，实现JSON传递(Demo)_4gl json

测试环境: GP5.25 , fjs版本2.32,解析json所需要的jar依赖包 (PS: 如果没有记错是fjs2.32版本及以上才支持java bridge,所以GP 5.25以下的同学就不要用这种方式去测试)

测试内容: 利用此fjs版本对java bridge的支持,实现4gl调用WEB API,实现json传递 

测试步骤如下:

1.下载本次测试需要的jar依赖包，百度搜索就有 “Java 解析JSON，JSON-LIBjar包下载”。只是if-common.jar文件要稍微注意，这是别人写好的包，下载下来是没有的。（如果有java经的童鞋,想一下就知道这里面会写什么）


2.将下载的jar文件传到ERP服务器对应的目录：/u1/topprod/tiptop/ds4gl2/bin/javaad/jar。

3.修改环境变量 tiptop_env文件中的jar包引用路径。

tiptop_env位置：/u1/topprod/tiptop/bin/tiptop_env，

可使用VI直接进行编辑，然后保存。（注意：多个环境变量以 冒号 隔开，最后一个环境变量时用 分号 结束）

4.编写4gl代码，重点将上传到服务器中的jar包，通过import方式导入到4gl代码中，以便调用。（目前已写成公共函数放lib/cl_web_api.4gl）

基本思路：将URL及要传递的JSON格式数据作为参数传入接口，将接口返回的数据/对象进行解析，存入一个随机创建的临时表（随机：表名不会重复，临时表为会话类型），回传给4gl临时表，供4gl再次处理。

4gl调用此lib,参数3传入不同的值,会有两种回传结果: 1.返回临时表名2.返回对象。

 

5.<第一种:返回临时表名>

调用lib下的方法CALLcl_web_api(p_Url,p_Post_Json,p_Type,p_Nouse2)，

设置第三个参数p_Type = 1, 返回临时表名，临时表内容为API接口返回的JSON数据，程序调用示例:

 

 根据回传的表名做一个简单的FOREACH测试：

 

6.<第二种:返回对象>

调用lib下的方法CALLcl_web_api(p_Url,p_Post_Json,p_Type,p_Nouse2)，

设置第三个参数p_Type = 2, 返回临对象，程序调用示例：

  

7.有个前提很重要，如果是要访问外部的WEB API接口，ERP服务器要一定可以访问外网；当然如果不方便让ERP服务器访问外网，就调用局域网下发布WEB API接口也是可以的。

                                              Author : Kellan

                                                Q Q :   309200966

                                                          Date:  2018年3月26日11:32:49

干货奉送!!!  cl_web_api.4gl源码如下:

  1. `
  2. # Prog. Version..: '5.25.11-12.12.11(00010)'     #
  3. #<-------------------------------------------------------------------------------------------------------------->
  4. # Library name.....: cl_web_api.4gl
  5. # Descriptions.....: 4GL提交Json到Web,获取Web返回的对象,并进行解析.(4GL调用外部Web API)
  6. # Memo.............: Two days,so funny. Where there is a will,there is a way..Ha-Ha-Ha..
  7. # Usage............: CALL cl_web_api(p_Url,p_Post_Json,p_Type,p_Nouse2) RETURNING p_Temp_Tab/object
  8. # param_In_1.......: p_Url , type=String 
  9. #     <--Example-->:   p_Url = "http://xxx.xxx.x.xx/2wm/public/index.php/api/Index/uploadTest?a=test"  
  10. # param_In_2.......: p_Post_Json , type=String 
  11. #     <--Example-->:   p_Post_Json = 'postData=[{"rec_id": "1","name": "匡奎"},{"rec_id": "2","name": "李聚"}]'
  12. # param_In_3.......: p_Type , type= Integer (type = 1 返回表名  type = 2 返回对象 )  
  13. # param_In_4.......: p_Nouse2 , type=String
  14. # 
  15. # param_Out_1......: p_Temp_Tab, type = String, Create temp table with random.
  16. # 
  17. # Date & Authors...: 2018-03-23/24  By Kellan & Andrew
  18. #<-------------------------------------------------------------------------------------------------------------->
  19.  
  20. IMPORT os                                               
  21. IMPORT com
  22. IMPORT JAVA net.sf.json.JSON                            
  23. IMPORT JAVA net.sf.json.JSONArray
  24. IMPORT JAVA net.sf.json.JSONObject
  25. IMPORT JAVA com.lifesense.common.HttpUtils  
  26. IMPORT util 
  27.                                        
  28. DATABASE ds        
  29. GLOBALS "../../config/top.global"    
  30.  
  31. FUNCTION cl_web_api(p_Url,p_Post_Json,p_Type,p_Nouse2)
  32.   DEFINE p_Url                       STRING,
  33.          p_Post_Json                 STRING,
  34.          p_Type                      INTEGER ,
  35.          p_Nouse2                    STRING                 
  36.   DEFINE l_rData                     STRING,
  37.          l_i                         INTEGER,
  38.          l_i_i                       INTEGER         
  39.   DEFINE w                           net.sf.json.JSONObject  #获取接口回传的对象     
  40.   DEFINE jsony,jsonykey              net.sf.json.JSONArray   
  41.   DEFINE jsonwx                      net.sf.json.JSONObject
  42.   DEFINE l_str                       STRING    
  43.   DEFINE l_tab_colum                 STRING,
  44.          l_tem_tab_name              STRING,
  45.          l_json_values               STRING, 
  46.          l_ins_values                STRING  
  47.   DEFINE l_ins_sql                   STRING,
  48.          l_msg                       STRING 
  49.                   
  50.   #组合URL,提交参数的JSON格式,返回对象 w
  51.   LET l_tab_colum = " "   
  52.   LET g_success = 'Y'          
  53.   TRY
  54.       CALL HttpUtils.getJSONObject(p_Url,p_Post_Json) RETURNING w  
  55.   CATCH  
  56.      LET l_msg = "ERROR :",STATUS,"==>API接口通讯失败!"
  57.      CALL cl_err(l_msg,"!",1)       
  58.      IF p_Type = 1 THEN 
  59.         RETURN " "
  60.      ELSE 
  61.         RETURN w 
  62.      END IF          
  63.   END TRY
  64.      
  65.   IF p_Type = 2 THEN 
  66.      RETURN w 
  67.   END IF 
  68.   #web端固定回传对象为rData  
  69.   LET l_rData = w.getString("rData")    
  70.   CALL cl_err(l_rData,'!',1)
  71.    
  72.   #根据回传对象rData解析为数组
  73.   LET jsony = w.getJSONArray("rData")  
  74.   IF jsony.size()=0 THEN
  75.      CALL cl_err("获取回传值失败!",'!',1)
  76.      RETURN " "
  77.   END IF  
  78. #begin----------------------------------create temp table------------------------------------------       
  79. #循环json的key值作为字段创建一个临时表:l_tem_tab_name.临时表字段统一用varhcar(4000)顶额 
  80.          LET jsonwx = JSONObject.fromObject(jsony.getString(0)) 
  81.          LET jsonykey = jsonwx.names()                            #json key获取 array
  82.          FOR l_i_i = 0 TO jsonykey.size()-1    
  83.              IF cl_nvl(jsonykey.getString(l_i_i)," ") = " " THEN 
  84.                 CALL cl_err("服务器回传的JSON格式key值为空,这是不允许的!","!",1)
  85.                 LET g_success = 'N'
  86.                 EXIT FOR 
  87.              END IF  
  88.                 LET l_tab_colum = l_tab_colum,' ',
  89.                                   jsonykey.getString(l_i_i),'  VARCHAR(4000)',','              
  90.          END FOR                 
  91.      IF g_success = 'N' THEN 
  92.         RETURN " "
  93.      END IF    
  94.      CALL cl_operation_str(l_tab_colum) RETURNING l_tab_colum
  95.      CALL cl_create_temp_table(l_tab_colum) RETURNING l_tem_tab_name
  96.      IF cl_nvl(l_tem_tab_name," ") = " " THEN         
  97.         RETURN " "
  98.      END IF 
  99. #end----------------------------------create temp table------------------------------------------ 
  100.       
  101. #begin----------------------------------insert data into temp table------------------------------  
  102. #两层循环,获取key对应的value值:l_values,组合出插入临时表的value值('column1','column2'.......),并写入临时表 
  103.      FOR l_i = 0 TO jsony.size()-1
  104.          LET jsonwx = JSONObject.fromObject(jsony.getString(l_i)) 
  105.          LET jsonykey = jsonwx.names()                            #json key获取 array
  106.          LET l_ins_values = " "
  107.          LET l_json_values = " "
  108.          FOR l_i_i = 0 TO jsonykey.size()-1  
  109.              LET l_json_values = jsonwx.getString(jsonykey.getString(l_i_i)) #根据json key 获取对应的value值
  110.              IF cl_nvl(l_json_values," ") = " " THEN 
  111.                 LET l_json_values = " "
  112.              END IF 
  113.              LET l_ins_values = l_ins_values," ","'",l_json_values,"'",","   #json key对应的values可能有特殊符号待处理?           
  114.          END FOR         
  115.         CALL cl_operation_str(l_ins_values) RETURNING l_ins_values
  116.         LET l_ins_sql = " INSERT INTO ",l_tem_tab_name," ",
  117.                         "      VALUES ",l_ins_values
  118.         PREPARE l_ins_sql_pb FROM l_ins_sql
  119.         EXECUTE l_ins_sql_pb  
  120.         IF STATUS THEN 
  121.            CALL cl_err("写入临时表失败!","1",1)
  122.            RETURN " "
  123.         END IF                                                
  124.      END FOR  
  125. #end----------------------------------insert data into temp table------------------------------     
  126.   RETURN l_tem_tab_name
  127. END FUNCTION 
  128.  
  129. FUNCTION cl_create_temp_table(p_tab_colum)
  130.   DEFINE p_tab_colum               STRING 
  131.   DEFINE l_cre_temp_tab_sql        STRING,
  132.          l_tab_name                STRING, 
  133.          l_random                  INTEGER, 
  134.          l_ymd                     VARCHAR(20),
  135.          ls_time                   STRING 
  136.  
  137.         CALL util.Math.rand(10000) RETURNING l_random
  138.             LET ls_time = TIME
  139.             LET l_tab_name = g_prog CLIPPED, "_",
  140.                             TODAY USING "YYMMDD", "_",
  141.                             ls_time.subString(1,2), ls_time.subString(4,5), ls_time.subString(7,8),'_',l_random
  142.         CALL cl_replace_str(l_tab_name,' ','') RETURNING l_tab_name
  143.         LET l_cre_temp_tab_sql = " Create Global Temporary Table ",          #两种方式创建临时表1,会话类型;2,事务类型
  144.                                  " ",l_tab_name," ",
  145.                                  " ",p_tab_colum," On Commit Preserve Rows " #本次选择会话类型创建
  146.         PREPARE l_cre_temp_tab_pb FROM l_cre_temp_tab_sql
  147.         EXECUTE l_cre_temp_tab_pb
  148.         IF STATUS THEN 
  149.            CALL cl_err("创建临时表出错"||l_tab_name,'!',1)
  150.            RETURN " "
  151.         END IF          
  152.         RETURN l_tab_name         
  153. END FUNCTION 
  154.  
  155. FUNCTION cl_operation_str(p_str)
  156.   DEFINE p_str           STRING        
  157.         LET p_str = p_str.substring(3,length(p_str))      #去掉开头的空格
  158.         LET p_str = p_str.substring(1,length(p_str)-1)    #去掉最后一个逗号
  159.         LET p_str = '(',p_str,')'                         #外层加上括号
  160.         RETURN p_str 
  161. END FUNCTION

相关工具

JSON格式化

在线JSON格式化工具，支持压缩和美化

JSON验证

验证JSON格式是否正确

JSON转换

JSON转XML、CSV等格式

JSON美化

美化JSON数据，提高可读性